number函數的使用方法，c語言isnumber函數的使用方法,[轉載]ISNUMBER函數詳解_Excel公式教程

【語法】ISNUMBER(value)

檢測一個數值是否數字值，是則返回TRUE，否則返回FALSE。

Value?必需。待檢測的數值，可以是任意類型的單值。

number函數的使用方法。可用TYPE函數代替ISNUMBER函數，ISNUMBER(value)可寫成TYPE(value)=1。

【用法】

一、參數value可以是一個單元格引用；檢測該單元格的值是不是數字值。

如果單元格為空，ISNUMBER函數返回FALSE。

ISNUMBER函數，(一)用于數據有效性。

例如，要限制單元格A1中只能輸入數字值，可先定位到單元格A1，然后打開“數據有效性”對話框，在“設置”選項卡“允許”下面的下拉菜單中選擇“自定義”，在“公式”輸入框中輸入以下公式：

=ISNUMBER(A1)

(二)用于條件格式。

c語言isdigit函數用法，例如，當單元格A1是數字值時，顯示為特定的格式，可設置以下條件格式公式：

=ISNUMBER(A1)

與自定義格式代碼比較，條件格式可以給單元格指定更多的格式，比如可以指定字體顏色和背景色、字形字號、下劃線、刪除線、上下標、邊框線等；另外，條件格式可以檢測當前單元格以外的其他單元格。

(三)用于函數中的邏輯值參數

c語言中%s和%c、例如，以下公式，當B1、D1、F1三個單元格都輸入了數字值，則返回“通過”，否則返回“請完善”：

=IF(AND(ISNUMBER(B1),ISNUMBER(D1),ISNUMBER(F1)),"通過","請完善")

二、參數value可以是一個嵌套的文本查找函數；檢測該函數能否找到指定的文本。

文本查找函數(FIND、FINDB、SEARCH、SEARCHB)如果找到指定文本，將返回數字值來表示找到的位置，否則返回錯誤值#VALUE!。

vbtab函數，(一)用于條件格式。如果單元格包含指定的特征文本，則以特殊格式顯示。

1、單元格A1如果包含文本“海爾”，則以高亮顯示。可在A1條件格式設置以下公式及高亮格式：

=ISNUMBER(FIND("海爾",A1))

其實這個公式可以簡寫成：

columns函數。=FIND("海爾",A1)

2、單元格A1如果包含文本“海爾”或“美的”，則以粗體顯示。可在A1條件格式設置以下公式及粗體格式：

=OR(ISNUMBER(FIND("海爾",A1)),ISNUMBER(FIND("美的",A1)))?或

=ISNUMBER(FIND("海爾",A1))+ISNUMBER(FIND("美的",A1))

3、把特征文本“海爾”“美的”“松下”放在單元格C1:C3，單元格A1如果包含這些文本，則以斜體顯示。可在A1條件格式設置以下公式及斜體格式：

=OR(ISNUMBER(FIND(C$1:C$3,A1)))

4、把特征文本以數組常量的形式指定給一個名稱，例如創建一個名稱TZZ，其引用位置的公式為={"海爾","美的","松下"}。當單元格A1包含特征文本時以紅色顯示。可在A1條件格式設置以下公式及紅色字體：

=OR(ISNUMBER(FIND(TZZ,A1)))

由于條件格式公式不能直接使用數組常量，所以這里借助了名稱來間接使用數組常量。

(二)對包含特征文本的行求和。如圖：

對“海爾”牌家電的銷量求和，公式如下：

=SUMPRODUCT(ISNUMBER(FIND("海爾",A2:A7))*B2:B7)?或

=SUMIF(A2:A7,"*海爾*",B2:B7)

對“海爾”“三洋”牌家電的銷量求和，公式如下：

=SUMPRODUCT(ISNUMBER(FIND({"海爾","三洋"},A2:A7))*B2:B7)?或

=SUM(SUMIF(A2:A7,{"*海爾*","*三洋*"},B2:B7))?或

{=SUMPRODUCT(ISNUMBER(FIND(TRANSPOSE(D2:D3),A2:A7))*B2:B7)}?或

{=SUM(SUMIF(A2:A7,"*"&D2:D3&"*",B2:B7))}

三、參數value可以是一個嵌套的MATCH函數；檢測MATCH函數能否找到指定的值。

(一)如果單元格的值在某列表中找得到，則以特殊格式顯示。

如圖。如果單元格A1的值在B列中找得到，則A1以紅底高亮顯示。可在A1條件格式設置以下公式及紅色底紋：

=ISNUMBER(MATCH(A1,$B:$B,))

其實這個公式可以簡寫成：

=MATCH(A1,$B:$B,)

(二)對符合某些值的行求和。

如圖。當A列的項目，在D列中出現時，對其B列的數字求和，公式如下：

=SUMPRODUCT(ISNUMBER(MATCH(A1:A6,D:D,))*B1:B6)